谷歌浏览器一键翻译功能用不了?教你怎么修复

近日,发现谷歌浏览器的右键一键翻译突然失效了。

遇到其他语言的网站,谷歌的右键的网页翻译真乃神器。

然而现在不能正常使用:

虽然不清楚到底是什么原因导致该状况,可能翻译接口被干掉了?可能谷歌关闭了中国的翻译服务?

小编教大家一步恢复谷歌浏览器右键网页翻译功能:

第一个方法(适合会计算机基础的用户)

1.打开C:\Windows\System32\drivers\etc目录

2.找到Hosts文件,按图所示修改后点确定

3.修改hosts文件

203.208.40.66 translate.google.com

203.208.40.66 translate.googleapis.com

4.保存(Ctrl+S)

如有问题可以关注VX公众号「时不待我」提问!

第二个方法(适合普通用户):

小编给大家提供了一个脚本文件(见文章末尾)。

原理是获取谷歌翻译国内的地址,然后将该地址加入系统的 hosts 文件中。

脚本已自动为大家完成了上述操作,同时智能选择了最快的翻译服务器。

1.在桌面上点击右键,新建文本文档(123.txt)。

2.将脚本文件复制到记事本中(123.txt),保存(Ctrl+S)

3.点击123.txt右键重命名,将记事本改为123.bat(不会修改文件后缀请百度一下)

4.右键123.bat在弹出的菜单中点击【以管理员身份运行】即可。

成功之后就可以使用翻译功能了:

脚本文件:

:: Copyright (c)2022 https://bookfere.com
:: This is a batch script for fixing Google Translate and making it available
:: in the Chinese mainland. If you experience any problem, visit the page below:
:: https://bookfere.com/post/1020.html

@setlocal enabledelayedexpansion
@echo off

set "source_domain=google.cn"
set "target_domain=translate.googleapis.com"

set "hosts_file=C:\Windows\System32\drivers\etc\hosts"

for /f "skip=4 tokens=2" %%a in ('"nslookup %source_domain% 2>NUL"') do set ip=%%a
set "old_rule=null"
set "new_rule=%ip% %target_domain%"

for /f "tokens=*" %%i in ('type %hosts_file%') do (
    set "line=%%i"
    :: Retrieve the rule If the target domain has been exists in the line.
    if not "!line:%target_domain%=!"=="%%i" set "old_rule=%%i"
)

if not "%old_rule%"=="null" (
    if not "%old_rule%"=="%new_rule%" (
        echo Deleting the rule "%old_rule%"
        echo Adding the rule "%new_rule%"
        for /f "tokens=*" %%i in ('type "%hosts_file%" ^| find /v /n "" ^& break ^> "%hosts_file%"') do (
            set "rule=%%i"
            set "rule=!rule:*]=!"
            if "%old_rule%"=="!rule!" set "rule=%new_rule%"
            >>%hosts_file% echo(!rule!
        )
    ) else (
        echo The rule already exists, nothing to do.
    )
) else (
    echo Adding the rule "%new_rule%"
    echo.>>%hosts_file%
    echo.>>%hosts_file%
    echo # Fix Google Translate CN>>%hosts_file%
    echo %new_rule%>>%hosts_file%
)

echo Done.
pause

发表回复

您的电子邮箱地址不会被公开。 必填项已用*标注